Contingut

# Funcions del full de càlcul

Aquesta secció conté descripcions de les funcions del full de càlcul i en mostra exemples.

Per a accedir a aquesta ordre...

Insereix ▸ Funció ▸ categoria Full de càlcul

## funció TIPUS.ERROR

Retorna un nombre que representa un tipus d'error específic, o el valor d'error #N/D, si no hi ha cap error.

## LOOKUP

Look for criterion in an already-sorted array, and return a corresponding result. Returns the contents of a cell either from a one-row or one-column range.

## STYLE

Aplica un estil a la cel·la que conté la fórmula.

## ADREÇA

Retorna una adreça de cel·la (referència) en forma de text en funció dels nombres de fila i de columna especificats. Podeu determinar si l'adreça s'ha d'interpretar com a adreça absoluta (per exemple, $A$1), com a adreça relativa (per exemple, A1) o en forma mixta (A$1 o $A1). També podeu indicar el nom del full.

For interoperability the ADDRESS and INDIRECT functions support an optional parameter to specify whether the R1C1 address notation instead of the usual A1 notation should be used.

A ADREÇA, el paràmetre s'insereix com a quart paràmetre, de manera que el paràmetre de nom de full opcional es desplaça a la cinquena posició.

A INDIRECTE, el paràmetre s'afegeix com a segon paràmetre.

In both functions, if the argument is inserted with the value 0, then the R1C1 notation is used. If the argument is not given or has a value other than 0, then the A1 notation is used.

In case of R1C1 notation, ADDRESS returns address strings using the exclamation mark '!' as the sheet name separator, and INDIRECT expects the exclamation mark as sheet name separator. Both functions still use the dot '.' sheet name separator with A1 notation.

Si obriu documents amb format ODF 1.0/1.1, les funcions ADREÇA que mostren un nom de full com a quart paràmetre desplaçaran aquest nom de full per tal que esdevingui el cinquè paràmetre, i inseriran un nou quart paràmetre amb el valor 1.

Si deseu un document en format ODF 1.0/1.1, en cas que les funcions ADREÇA tinguin un quart paràmetre, el suprimiran.

No deseu el full de càlcul en l'antic format ODF 1.0/1.1 si el nou quart paràmetre de la funció ADREÇA s'ha utilitzat amb valor 0.

La funció INDIRECTE es desa sense fer la conversió al format ODF 1.0/1.1. Si hi ha un segon paràmetre, les versions antigues del Calc retornaran un error per a aquesta funció.

#### Sintaxi

ADREÇA(Fila; Columna [; Abs [; A1 [; "Full"]]])

Fila representa el número de fila de la referència de cel·la.

Columna representa el número de columna de la referència de cel·la (el número, no la lletra).

Abs determina el tipus de referència:

1: absoluta ($A$1)

2: el tipus de referència de la fila és absolut; la referència de la columna és relativa (A$1)

3: fila (relativa); columna (absoluta) ($A1)

4: relativa (A1)

A1 (optional) - if set to 0, the R1C1 notation is used. If this parameter is absent or set to another value than 0, the A1 notation is used.

Full representa el nom del full. Cal col·locar-lo entre cometes dobles.

### Exemple:

=ADREÇA(1;1;2;"Full2") retorna: Full2.A$1

If the formula above is in cell B2 of current sheet, and the cell A1 in sheet 2 contains the value -6, you can refer indirectly to the referenced cell using a function in B2 by entering =ABS(INDIRECT(B2)). The result is the absolute value of the cell reference specified in B2, which in this case is 6.

## AREES

Retorna el nombre d'intervals individuals que pertanyen a un interval múltiple. Un interval pot estar format per cel·les contigües o per una sola cel·la.

La funció espera un sol argument. Si definiu diversos intervals, els heu de posar entre parèntesis addicionals. Es poden introduir diversos intervals utilitzant el punt i coma (;) com a divisor, però es converteix automàticament en l'operador de titlla (~). La titlla s'utilitza per unir intervals.

#### Sintaxi

AREES(Referència)

Referència representa la referència a la cel·la o a un interval de cel·les.

#### Exemple

=AREES((A1:B3;F2;G1)) retorna 3, ja que és una referència a tres cel·les i/o àrees. Després de l'entrada, es converteix en =AREES((A1:B3~F2~G1)).

=AREES(Totes) retorna 1 si heu definit una àrea anomenada Totes a Dades ▸ Defineix l'interval.

## COINCIDEIX

Retorna la posició relativa d'un element contingut en una matriu que coincideixi amb un valor determinat. La funció retorna la posició del valor que s'ha trobat en la matriu_de_cerca en forma de nombre.

#### Sintaxi

MATCH(Search; LookupArray [; Type])

Search is the value which is to be searched for in the single-row or single-column array.

MatriuDeCerca és la referència que se cerca. Una matriu de cerca pot constar d'una sola fila o columna, o bé pot formar part d'una sola fila o columna.

Tipus pot tenir els valors 1, 0 o -1. Si Tipus = 1 o si manca aquest paràmetre opcional, s'assumeix que la primera columna de la matriu de cerca està ordenada de manera ascendent. Si Tipus = -1 s'assumeix que la columna està ordenada de manera descendent. Això correspon a la mateixa funció del Microsoft Excel.

If Type = 1 or the third parameter is missing, the index of the last value that is smaller or equal to the search criterion is returned. For Type = -1, the index of the last value that is larger or equal is returned.

Unpredictable results are expected if Type takes values -1 or +1 and the LookupArray is not sorted.

If Type = 0, only exact matches are found. If the search criterion is found more than once, the function returns the index of the first matching value. Only if Type = 0 can you search for regular expressions (if enabled in calculation options) or wildcards (if enabled in calculation options).

The search supports wildcards or regular expressions. With regular expressions enabled, you can enter "all.*", for example to find the first location of "all" followed by any characters. If you want to search for a text that is also a regular expression, you must either precede every regular expression metacharacter or operator with a "\" character, or enclose the text into \Q...\E. You can switch the automatic evaluation of wildcards or regular expression on and off in LibreOffice - Preferences Tools - Options - LibreOffice Calc - Calculate.

When using functions where one or more arguments are search criteria strings that represents a regular expression, the first attempt is to convert the string criteria to numbers. For example, ".0" will convert to 0.0 and so on. If successful, the match will not be a regular expression match but a numeric match. However, when switching to a locale where the decimal separator is not the dot makes the regular expression conversion work. To force the evaluation of the regular expression instead of a numeric expression, use some expression that can not be misread as numeric, such as ".[0]" or ".\0" or "(?i).0".

#### Exemple

=COINCIDEIX(200;D1:D100) cerca el valor 200 en l'àrea D1:D100, que s'ha ordenat per la columna D. Tan bon punt es troba aquest valor, es retorna el nombre de la fila on s'ha trobat. Si es troba un valor més gran durant la cerca a la columna, es retorna el nombre de la fila anterior.

## COLUMNA

Returns the column number of a cell reference. If the reference is a cell the column number of the cell is returned; if the parameter is a cell area, the corresponding column numbers are returned in a single-row array if the formula is entered as an array formula. If the COLUMN function with an area reference parameter is not used for an array formula, only the column number of the first cell within the area is determined.

#### Sintaxi

COLUMNA([Referència])

Referència és la referència a una cel·la o a una àrea de cel·les de la qual s'ha de cercar el número de la primera columna.

Si no indiqueu cap referència, se cercarà el número de columna de la cel·la on s'introdueixi la fórmula. El LibreOffice Calc defineix automàticament la referència de la cel·la actual.

#### Exemple

=COLUMNA(A1) és igual a 1. La columna A és la primera columna de la taula.

=COLUMNA(C3:E3) és igual a 3. La columna C és la tercera columna de la taula.

=COLUMNA(D3:G10) retorna 4 perquè la columna D és la quarta columna de la taula i la funció COLUMNA no s'utilitza com a fórmula matricial. (En aquest cas, el primer valor de la matriu sempre s'utilitza com a resultat.)

{=COLUMNA(B2:B7)} i =COLUMNA(B2:B7) retornen 2 perquè la referència només conté la columna B com la segona columna de la taula. Atès que les àrees d'una sola columna només tenen un número de columna, és indiferent si la fórmula s'utilitza com a fórmula matricial o no.

=COLUMNA() retorna 3 si s'ha introduït la fórmula a la columna C.

{=COLUMNA(Conill)} retorna la matriu d'una sola fila (3, 4) si "Conill" és l'àrea anomenada (C1:D3).

## COLUMNES

Retorna el nombre de columnes de la referència determinada.

#### Sintaxi

COLUMNES(Matriu)

Matriu és la referència d'un interval de cel·les el nombre total de columnes del qual cal trobar. L'argument pot ser una única cel·la.

#### Exemple

=COLUMNES(B5) retorna 1 perquè una cel·la només conté una columna.

=COLUMNES(A1:C5) és igual a 3. La referència comprèn tres columnes.

=COLUMNES(Conill) retorna 2 si Conill és l'interval anomenat (C1:D3).

## CONSULTAH

Cerca un valor i una referència en les cel·les situades sota l'àrea seleccionada. Aquesta funció verifica si la primera fila d'una matriu conté un valor determinat. Tot seguit, la funció retorna el valor en una fila de la matriu, anomenada en l'Índex, en la mateixa columna.

The search supports wildcards or regular expressions. With regular expressions enabled, you can enter "all.*", for example to find the first location of "all" followed by any characters. If you want to search for a text that is also a regular expression, you must either precede every regular expression metacharacter or operator with a "\" character, or enclose the text into \Q...\E. You can switch the automatic evaluation of wildcards or regular expression on and off in LibreOffice - Preferences Tools - Options - LibreOffice Calc - Calculate.

When using functions where one or more arguments are search criteria strings that represents a regular expression, the first attempt is to convert the string criteria to numbers. For example, ".0" will convert to 0.0 and so on. If successful, the match will not be a regular expression match but a numeric match. However, when switching to a locale where the decimal separator is not the dot makes the regular expression conversion work. To force the evaluation of the regular expression instead of a numeric expression, use some expression that can not be misread as numeric, such as ".[0]" or ".\0" or "(?i).0".

#### Sintaxi

HLOOKUP(Lookup; Array; Index [; SortedRangeLookup])

For an explanation on the parameters, see: VLOOKUP (columns and rows are exchanged)

Gestió de cel·les buides

#### Exemple

Suppose we have built a small database table occupying the cell range A1:DO4 and containing basic information about 118 chemical elements. The first column contains the row headings “Element”, “Symbol”, “Atomic Number”, and “Relative Atomic Mass”. Subsequent columns contain the relevant information for each of the elements, ordered left to right by atomic number. For example, cells B1:B4 contain “Hydrogen”, “H”, “1” and “1.008”, while cells DO1:DO4 contain “Oganesson”, “Og”, “118”, and “294”.

| A | B | C | D | ... | DO
--- | --- | --- | --- | --- | --- | ---
1 | Element | Hidrogen | Heli | Liti | ... | Oganessó
2 | Símbol | H | He | Li | ... | Og
3 | Nombre atòmic | 1 | 2 | 3 | ... | 118
4 | Massa atòmica relativa | 1.008 | 4.0026 | 6.94 | ... | 294

=HLOOKUP("Lead"; $A$1:$DO$4; 2; 0) returns “Pb”, the symbol for lead.

=HLOOKUP("Gold"; $A$1:$DO$4; 3; 0) returns 79, the atomic number for gold.

=HLOOKUP("Carbon"; $A$1:$DO$4; 4; 0) returns 12.011, the relative atomic mass of carbon.

## CONSULTAV

Vertical search with reference to adjacent cells to the right. This function checks if a specific value is contained in the first column of an array. The function then returns the value in the same row of the column named by Index. If the SortedRangeLookup parameter is omitted or set to TRUE or one, it is assumed that the data is sorted in ascending order. In this case, if the exact Lookup is not found, the last value that is smaller than the criterion will be returned. If SortedRangeLookup is set to FALSE or zero, an exact match must be found, otherwise the error Error: Value Not Available will be the result. Thus with a value of zero the data does not need to be sorted in ascending order.

The search supports wildcards or regular expressions. With regular expressions enabled, you can enter "all.*", for example to find the first location of "all" followed by any characters. If you want to search for a text that is also a regular expression, you must either precede every regular expression metacharacter or operator with a "\" character, or enclose the text into \Q...\E. You can switch the automatic evaluation of wildcards or regular expression on and off in LibreOffice - Preferences Tools - Options - LibreOffice Calc - Calculate.

When using functions where one or more arguments are search criteria strings that represents a regular expression, the first attempt is to convert the string criteria to numbers. For example, ".0" will convert to 0.0 and so on. If successful, the match will not be a regular expression match but a numeric match. However, when switching to a locale where the decimal separator is not the dot makes the regular expression conversion work. To force the evaluation of the regular expression instead of a numeric expression, use some expression that can not be misread as numeric, such as ".[0]" or ".\0" or "(?i).0".

#### Sintaxi

=VLOOKUP(Lookup; Array; Index [; SortedRangeLookup])

Lookup is the value of any type looked for in the first column of the array.

Array is the reference, which is to comprise at least as many columns as the number passed in Index argument.

Índex és el número de la columna de la matriu que conté el valor que s'ha de retornar. La primera columna té el número 1.

SortedRangeLookup is an optional parameter that indicates whether the first column in the array contains range boundaries instead of plain values. In this mode, the lookup returns the value in the row with first column having value equal to or less than Lookup. E.g., it could contain dates when some tax value had been changed, and so the values represent starting dates of a period when a specific tax value was effective. Thus, searching for a date that is absent in the first array column, but falls between some existing boundary dates, would give the lower of them, allowing to find out the data being effective to the searched date. Enter the Boolean value FALSE or zero if the first column is not a range boundary list. When this parameter is TRUE or not given, the first column in the array must be sorted in ascending order. Sorted columns can be searched much faster and the function always returns a value, even if the search value was not matched exactly, if it is greater than the lowest value of the sorted list. In unsorted lists, the search value must be matched exactly. Otherwise the function will return #N/A with message: Error: Value Not Available.

Gestió de cel·les buides

#### Exemple

You want to enter the number of a dish on the menu in cell A1, and the name of the dish is to appear as text in the neighboring cell (B1) immediately. The Number to Name assignment is contained in the D1:E100 array. D1 contains 100, E1 contains the name Vegetable Soup, and so forth, for 100 menu items. The numbers in column D are sorted in ascending order; thus, the optional Sorted parameter is not necessary.

Introduïu la fórmula següent a B1:

=CONSULTAV(A1;D1:E100;2)

Tan bon punt introduïu un nombre a A1, B1 mostrarà el text corresponent que apareix a la segona columna de la referència D1:E100. Si introduïu un nombre que no existeix, apareixerà el text del nombre inferior següent. Per evitar que això passi, introduïu FALS com a últim paràmetre de la fórmula perquè es generi un missatge d'error quan s'introdueixi un nombre no existent.

## DDE

Retorna el resultat d'un enllaç basat en DDE. Si els continguts de la secció o de l'interval enllaçat canvien, el valor retornat també canviarà. Per veure els enllaços actualitzats, actualitzeu el full de càlcul o trieu Edita ▸ Enllaços. No es permeten els enllaços multiplataforma (per exemple, des d'una instal·lació del LibreOffice que s'executi en un ordinador amb el Windows a un document creat en un ordinador amb el Linux).

#### Sintaxi

DDE("Server"; "File"; "Range" [; Mode])

Servidor és el nom d'una aplicació de servidor. En el cas de les aplicacions del LibreOffice, el nom de servidor és «soffice».

Fitxer és el nom de fitxer complet, inclosa l'especificació del camí.

Interval és l'àrea que conté les dades que s'han d'avaluar.

Mode és un paràmetre opcional que controla el mètode pel qual el servidor DDE converteix les dades en nombres.

Mode | Efecte
--- | ---
0 o hi manca | Format numèric de l'estil de cel·la «Per defecte»
1 | Les dades sempre s'interpreten en el format estàndard de l'anglès americà.
2 | Les dades es recuperen com a text; no hi ha conversió a nombres

#### Exemple

=DDE("soffice";"c:\office\document\data1.ods";"sheet1.A1") reads the contents of cell A1 in sheet1 of the LibreOffice Calc spreadsheet data1.ods.

=DDE("soffice";"c:\office\document\motto.odt";"Today's motto") returns a motto in the cell containing this formula. First, you must enter a line in the motto.odt document containing the motto text and define it as the first line of a section named Today's Motto (in LibreOffice Writer under Insert - Section). If the motto is modified (and saved) in the LibreOffice Writer document, the motto is updated in all LibreOffice Calc cells in which this DDE link is defined.

## DESPLAÇAMENT

Retorna el valor d'un desplaçament de cel·la d'un nombre determinat de files i columnes a partir d'un punt de referència indicat.

This function is always recalculated whenever a recalculation occurs.

#### Sintaxi

OFFSET(Reference; Rows; Columns [; Height [; Width]])

Referència és la referència a partir de la qual la funció cerca la referència nova.

Files és el nombre de files amb què s'ha corregit la referència cap amunt (valor negatiu) o cap avall.

Files és el nombre de files amb què s'ha corregit la referència cap amunt (valor negatiu) o cap avall.

Alçada (opcional) és l'alçada vertical d'una àrea que comença en la posició de referència nova.

Amplada (opcional) és l'amplada horitzontal d'una àrea que comença en la nova posició de referència.

Els arguments Files i Columnes no han de conduir a zero o a un inici negatiu de fila o de columna.

Els arguments Alçada i Amplada no han de conduir a zero o a un comptatge negatiu de files o de columnes.

En les funcions del LibreOffice Calc, els paràmetres marcats com a «opcionals» es poden ometre quan no hi ha cap altre paràmetre que els segueixi. Per exemple, en una funció amb quatre paràmetres, en què els dos darrers estan marcats com a «opcionals», es pot ometre el paràmetre 4 o bé els paràmetres 3 i 4; en canvi, no es pot ometre únicament el paràmetre 3.

#### Exemple

=DESPLAÇAMENT(A1;2;2) retorna el valor de la cel·la C3 (A1 desplaçada dues files i dues columnes cap avall). Si C3 conté el valor 100, la funció retorna el valor 100.

=DESPLAÇAMENT(B2:C3;1;1) retorna una referència a B2:C3 desplaçada 1 fila i 1 columna cap a la dreta (C3:D4).

=DESPLAÇAMENT(B2:C3;-1;-1) retorna una referència a B2:C3 desplaçada una fila cap amunt i una columna cap a l'esquerra (A1:B2).

=DESPLAÇAMENT(B2:C3;0;0;3;4) retorna una referència cap a l'interval B2:C3 redimensionada a 3 files i 4 columnes (B2:E4).

=DESPLAÇAMENT(B2:C3;1;0;3;4) retorna una referència a B2:C3 desplaçada una fila redimensionada en 3 files i 4 columnes (B3:E5).

=SUMA(DESPLAÇAMENT(A1;2;2;5;6)) determina el total de l'àrea que comença a la cel·la C3, i que té una alçada de 5 files i una amplada de 6 columnes (àrea=C3:H7).

Si s'hi especifiquen l'Amplada o l'Alçada, la funció DESPLAÇAMENT retorna una referència a un interval de cel·les. Si Referència és una referència a una única cel·la y s'ometen tant Amplada com Alçada, es retorna una referència a una única cel·la.

## ENLLAÇ

Quan feu clic en una cel·la que conté la funció ENLLAÇ, s'obre l'enllaç.

If you use the optional CellValue parameter, the formula locates the URL, and then displays the text or number.

Per obrir una cel·la enllaçada amb el teclat, seleccioneu la cel·la i premeu F2 per entrar al mode d'edició; tot seguit, moveu el cursor al davant de l'enllaç, premeu Maj+F10 i trieu Obre l'enllaç.

#### Sintaxi

HYPERLINK("URL" [; CellValue])

URL specifies the link target. The optional CellValue parameter is the text or a number that is displayed in the cell and will be returned as the result. If the CellValue parameter is not specified, the URL is displayed in the cell text and will be returned as the result.

En les cel·les i elements de matriu buits, es retornarà el número 0.

#### Exemple

=HYPERLINK("http://www.example.org") displays the text "http://www.example.org" in the cell and executes the hyperlink http://www.example.org when clicked.

=HYPERLINK("http://www.example.org";"Click here") displays the text "Click here" in the cell and executes the hyperlink http://www.example.org when clicked.

=HYPERLINK("http://www.example.org";12345) displays the number 12345 and executes the hyperlink http://www.example.org when clicked.

=HYPERLINK($B4) where cell B4 contains http://www.example.org. The function adds http://www.example.org to the URL of the hyperlink cell and returns the same text which is used as formula result.

=HYPERLINK("http://www.";"Click ") & "example.org" displays the text Click example.org in the cell and executes the hyperlink http://www.example.org when clicked.

=HYPERLINK("#Sheet1.A1";"Go to top") displays the text Go to top and jumps to cell Sheet1.A1 in this document.

=HYPERLINK("file:///C:/writer.odt#Specification";"Go to Writer bookmark") displays the text "Go to Writer bookmark", loads the specified text document and jumps to bookmark "Specification".

=HYPERLINK("file:///C:/Documents/";"Open Documents folder") displays the text "Open Documents folder" and shows the folder contents using the standard file manager in your operating system.

The function tries to bridge with system specificities. For example, "c:\path to\file.ext" will be properly interpreted as "file:///c:/path%20to/file.ext" on Windows, or ".." will lead to the parent directory of the document.

## EXTREUDADESPIVOT

La funció EXTREUDADESPIVOT retorna un valor de resultat d'una taula dinàmica. Aquest valor s'adreça mitjançant noms de camp i d'element, de manera que continuarà essent vàlid encara que canviï la disposició de la taula dinàmica.

#### Sintaxi

Es poden utilitzar dues definicions de sintaxi diferents:

GETPIVOTDATA(TargetField; pivot table[; Field 1; Item 1][; ... [Field 126; Item 126]])

o

EXTREUDADESPIVOT(TaulaDinàmica; Restriccions)

S'assumeix la segona sintaxi si s'indiquen exactament dos paràmetres, el primer dels quals és una referència de cel·la o d'interval de cel·les. En la resta de casos, s'assumeix la primera sintaxi. L'Auxiliar de funcions mostra la primera sintaxi.

### Primera sintaxi

CampDeDestinació és una cadena que selecciona un dels camps de dades de la taula dinàmica. La cadena pot ser el nom de la columna d'origen o del camp de dades tal com es mostra a la taula (com ara "Suma - Vendes").

TaulaDinàmica és una referència a una cel·la o a un interval de cel·les que es troba dins una taula dinàmica o que conté una taula dinàmica. Si l'interval de cel·les conté diverses taules dinàmiques, s'utilitza l'última taula creada.

Si no s'indica cap parell Camp n / Element n, es retorna la suma total. En cas contrari, cada parell afegeix una restricció que el resultat ha de complir. Camp n és el nom d'un camp de la taula dinàmica. Element n és el nom d'un element d'aquest camp.

Si la taula dinàmica només conté un valor de resultat que compleixi totes les restriccions, o un resultat de subtotal que agrupi tots els valors coincidents, es retorna aquest resultat. Si no hi ha cap resultat que coincideixi, o n'hi ha diversos sense cap subtotal, es retorna un error. Aquestes condicions s'apliquen als resultats que inclou la taula dinàmica.

Si les dades font contenen entrades que estan amagades a causa de la configuració de la taula dinàmica, s'ignoren. L'ordre de les parelles Camp/Element no és important. En els noms de camp i d'element no es distingeix entre majúscules i minúscules.

If no constraint for a filter is given, the field's selected value is implicitly used. If a constraint for a filter is given, it must match the field's selected value, or an error is returned. Filters are the fields at the top left of a pivot table, populated using the "Filters" area of the pivot table layout dialog. From each filter, an item (value) can be selected, which means only that item is included in the calculation.

Els valors de subtotal de la taula dinàmica només s'utilitzen si fan servir la funció «auto» (llevat de si s'indica en la restricció; en aquest cas, vegeu Segona sintaxi tot seguit).

### Segona sintaxi

TaulaDinàmica té el mateix significat que en la primera sintaxi.

Restriccions és una llista separada per espais. Les entrades poden contenir cometes (cometes simples). Tota la cadena ha d'estar entre cometes (cometes dobles), si no és que referencieu la cadena des d'una altra cel·la.

Una de les entrades pot ser el nom del camp de dades. El nom del camp de dades es pot ometre si la taula dinàmica només conté un camp de dades; altrament, ha d'estar present.

Cadascuna de les altres entrades indica una restricció en la forma Camp[Element] (amb els caràcters literals [ i ]), o només Element si el nom de l'element és únic en tots els camps que s'utilitzen en la taula dinàmica.

Si s'afegeix un nom de funció en la forma Camp[Element;Funció], la restricció només coincidirà amb els valors de subtotal que utilitzin la funció. Els noms de funció possibles són Suma, Comptatge, Mitjana, Max, Min, Producte, Comptatge (només nombres), DesVest (mostra), DesvEstP (població), Var (mostra) i VarP (població), sense distingir entre majúscules i minúscules.

## FILA

Returns the row number of a cell reference. If the reference is a cell, it returns the row number of the cell. If the reference is a cell range, it returns the corresponding row numbers in a one-column Array if the formula is entered as an array formula. If the ROW function with a range reference is not used in an array formula, only the row number of the first range cell will be returned.

#### Sintaxi

FILA([Referència])

Referència és una cel·la, una àrea o el nom d'una àrea.

Si no indiqueu una referència, es trobarà el número de fila de cel·la on s'introdueix la fórmula. El LibreOffice Calc defineix automàticament la referència de la cel·la actual.

#### Exemple

=FILA(B3) retorna 3 perquè la referència es refereix a la tercera fila de la taula.

{=FILA(D5:D8)} retorna la matriu d'una sola columna (5, 6, 7, 8) perquè la referència indicada conté de la fila 5 a la 8.

=FILA(D5:D8) retorna 5 perquè la funció FILA no s'utilitza com una fórmula matricial i només es retorna el nombre de la primera fila de la referència.

{=FILA(A1:E1)} i =FILA(A1:E1) retornen 1 perquè la referència només conté la fila 1 com la primera columna de la taula. (Com que les àrees d'una sola fila només tenen un número de fila, no hi ha cap diferència si la fórmula s'utilitza en una fórmula matricial o no.)

=FILA() retorna 3 si s'ha introduït la fórmula a la fila 3.

{=FILA(Conill)} retorna la matriu d'una sola columna (1, 2, 3) si "Conill" és l'àrea anomenada (C1:D3).

## FILES

Retorna el nombre de files d'una referència o matriu.

#### Sintaxi

FILES(Matriu)

Matriu és la referència o l'àrea anomenada de la qual s'ha de determinar el nombre total de files.

#### Exemple

=FILES(B5) retorna 1 perquè una cel·la només conté una fila.

=FILES(A10:B12) retorna 3.

=FILES(Conill) retorna 3 si "Conill" és l'àrea anomenada (C1:D3).

## FULL

Returns the sheet number of either a reference or a string representing a sheet name. If you do not enter any parameters, the result is the sheet number of the spreadsheet containing the formula.

#### Sintaxi

SHEET([Reference])

Referència és opcional i és la referència a una cel·la, a una àrea o a una cadena de nom de full.

#### Exemple

=SHEET(Sheet2.A1) returns 2 if Sheet2 is the second sheet in the spreadsheet document.

=SHEET("Sheet3") returns 3 if Sheet3 is the third sheet in the spreadsheet document.

## FULLS

Determina el nombre de fulls d'una referència. Si no introduïu cap paràmetre, retorna el nombre de fulls del document actual.

#### Sintaxi

SHEETS([Reference])

Referència és la referència a un full o a una àrea. Aquest paràmetre és opcional.

#### Exemple

=FULLS(Full1.A1:Full3.G12) retorna 3 si el Full1, el Full2 i el Full3 existeixen en la seqüència indicada.

## INDEX

INDEX returns a reference, a value or an array of values from a reference range, specified by row and column index number or array of row and array of columns index numbers, and an optional range index.

INDEX() returns a reference if the argument is one or more references. When used in a cell in the form =INDEX(), the reference is resolved and the values displayed. When INDEX() is used in arguments of other functions, =FUNCTION(INDEX()...), the function gets the reference passed that was returned by INDEX(). Returning a reference is different from returning an array of values for functions that handles them differently.

#### Sintaxi

INDEX(Reference [; [Row] [; [Column] [; Range]]])

Reference is a reference, entered either directly or by specifying a range name. If the reference consists of multiple ranges, you must enclose the list of references or range names in parentheses, or either use the tilde (~) range concatenation operator or define a named range with multiple areas.

Row (optional) represents the row or the array of row indexes of the reference range, for which to return a value. In case of zero or omitted (no specific row) all referenced rows are returned.

Column (optional) represents the column or array of column indexes of the reference range, for which to return a value. In case of zero or omitted (no specific column) all referenced columns are returned.

If Row, Column or both are omitted or defined as arrays of indexes, the INDEX function must be entered as an array function.

Range (optional) represents the index of the subrange if referring to a multiple range, default is 1.

#### Exemple

{=INDEX({1,3,5;7,9,10},{2;1},1)} return a 2 row array containing 7 and 1. The row index {2;1} pick row 2 then row 1. The columns index 1 picks the first column.

{=INDEX(D3:G12,{1;2;3;4},{3,1})} return a 4 rows by 2 columns array. The row index array {1;2;3;4} picks rows 3 to 6 and {3;1} picks the third (F) and first column (D). Columns 1 and 3 of the source reference are swapped in the resulting array.

=INDEX(Preus;4;1) retorna el valor de la fila 4 i de la columna 1 de l'interval de base de dades que heu definit a Dades ▸ Defineix com a Preus.

=INDEX(SumaX;4;1) retorna el valor de l'interval SumaX de la fila 4 i la columna 1 tal com s'ha definit a Full ▸ Intervals i expressions amb nom ▸ Defineix.

{=INDEX(A1:B6;1)} returns the values of the first row of A1:B6. Enter the formula as an array formula.

{=INDEX(A1:B6;0;1)} returns the values of the first column of A1:B6. Enter the formula as an array formula.

=INDEX(A1:B6;1;1) indica el valor de la part superior esquerra de l'interval A1:B6.

{=INDEX((A1:B6;C1:D6);0;0;2)} returns the values of the second range C1:D6 of the multiple range. Enter the formula as an array formula.

Temes relacionats

INDEX wiki page.

## INDIRECTE

Retorna la referència especificada per una cadena de text. Aquesta funció també pot utilitzar-se per retornar l'àrea d'una cadena corresponent.

This function is always recalculated whenever a recalculation occurs.

For interoperability the ADDRESS and INDIRECT functions support an optional parameter to specify whether the R1C1 address notation instead of the usual A1 notation should be used.

A ADREÇA, el paràmetre s'insereix com a quart paràmetre, de manera que el paràmetre de nom de full opcional es desplaça a la cinquena posició.

A INDIRECTE, el paràmetre s'afegeix com a segon paràmetre.

In both functions, if the argument is inserted with the value 0, then the R1C1 notation is used. If the argument is not given or has a value other than 0, then the A1 notation is used.

In case of R1C1 notation, ADDRESS returns address strings using the exclamation mark '!' as the sheet name separator, and INDIRECT expects the exclamation mark as sheet name separator. Both functions still use the dot '.' sheet name separator with A1 notation.

Si obriu documents amb format ODF 1.0/1.1, les funcions ADREÇA que mostren un nom de full com a quart paràmetre desplaçaran aquest nom de full per tal que esdevingui el cinquè paràmetre, i inseriran un nou quart paràmetre amb el valor 1.

Si deseu un document en format ODF 1.0/1.1, en cas que les funcions ADREÇA tinguin un quart paràmetre, el suprimiran.

No deseu el full de càlcul en l'antic format ODF 1.0/1.1 si el nou quart paràmetre de la funció ADREÇA s'ha utilitzat amb valor 0.

La funció INDIRECTE es desa sense fer la conversió al format ODF 1.0/1.1. Si hi ha un segon paràmetre, les versions antigues del Calc retornaran un error per a aquesta funció.

#### Sintaxi

INDIRECTE(Ref [; A1])

Ref representa una referència a una cel·la o a una àrea (en un formulari de text) per a la qual es retornen els continguts.

A1 (optional) - if set to 0, the R1C1 notation is used. If this parameter is absent or set to another value than 0, the A1 notation is used.

Si obriu un full de càlcul de l'Excel que utilitza adreces indirectes que s'han calculat a partir de funcions de cadena, les adreces del full no es traduiran automàticament. Per exemple, l'adreça de l'Excel a INDIRECTE("[nomdelfitxer]nomdelfull!"&B1) no es converteix en l'adreça del Calc a INDIRECTE("nomdelfitxer#nomdelfull."&B1).

#### Exemple

=INDIRECTE(A1) és igual a 100 si A1 conté C108 com a referència i la cel·la C108 conté un valor de 100.

=SUMA(INDIRECTE("a1:" & ADREÇA(1;3))) totalitza les cel·les de l'àrea A1 fins a la cel·la de la qual s'ha definit l'adreça amb la fila 1 i la columna 3. Això vol dir que es calcula el total de l'àrea A1:C1.

Temes relacionats

INDIRECT wiki page.

## TIPUSERROR

Retorna el nombre corresponent a un valor d'error que aparegui en una cel·la diferent. Amb l'ajuda d'aquest nombre, podeu generar un missatge d'error en forma de text.

Si es produeix un error, la funció retorna un valor lògic o numèric.

La barra d'estat mostra el codi d'error predefinit del LibreOffice si feu clic a la cel·la que conté l'error.

#### Sintaxi

TIPUSERROR(Referència)

Referència conté l'adreça de la cel·la on es produeix l'error.

#### Exemple

Si la cel·la A1 mostra Err:518, la funció =TIPUSERROR(A1) retorna el nombre 518.

#### Informació tècnica

This function is NOT part of the Open Document Format for Office Applications (OpenDocument) Version 1.3. Part 4: Recalculated Formula (OpenFormula) Format standard. The name space is

ORG.OPENOFFICE.ERRORTYPE

## TRIA

Utilitza un índex per retornar un valor d'una llista de fins a 30 valors.

#### Sintaxi

CHOOSE(Index; Value 1 [; Value 2 [; ... [; Value 30]]])

Índex és una referència o un nombre entre 1 i 30 que indica quin valor s'ha d'extreure de la llista.

Value 1, Value 2, ..., Value 30 is the list of values entered as a reference to a cell or as individual values.

#### Exemple

=TRIA(A1;B1;B2;B3;"Avui";"Ahir";"Demà"), per exemple, retorna el contingut de la cel·la B2 per a A1 = 2; per a A1 = 4, la funció retorna el text "Avui".

Temes relacionats

Funcions per categoria

Ens cal la vostra ajuda!